Gecko [ satitravel.com ]

Name	Size	Permission	Date
altTheme.tcl	3.46 KB	-rw-r--r--	2019-10-16 17:25
aquaTheme.tcl	1.95 KB	-rw-r--r--	2019-10-16 17:25
button.tcl	2.91 KB	-rw-r--r--	2019-10-16 17:25
clamTheme.tcl	4.49 KB	-rw-r--r--	2019-10-16 17:25
classicTheme.tcl	3.6 KB	-rw-r--r--	2019-10-16 17:25
combobox.tcl	12.13 KB	-rw-r--r--	2019-10-16 17:25
cursors.tcl	3.91 KB	-rw-r--r--	2019-10-16 17:25
defaults.tcl	4.25 KB	-rw-r--r--	2019-10-16 17:25
entry.tcl	16.01 KB	-rw-r--r--	2019-10-16 17:25
fonts.tcl	5.45 KB	-rw-r--r--	2019-10-16 17:25
menubutton.tcl	4.8 KB	-rw-r--r--	2019-10-16 17:25
notebook.tcl	5.49 KB	-rw-r--r--	2019-10-16 17:25
panedwindow.tcl	1.88 KB	-rw-r--r--	2019-10-16 17:25
progress.tcl	1.06 KB	-rw-r--r--	2019-10-16 17:25
scale.tcl	2.63 KB	-rw-r--r--	2019-10-16 17:25
scrollbar.tcl	3.02 KB	-rw-r--r--	2019-10-16 17:25
sizegrip.tcl	2.34 KB	-rw-r--r--	2019-10-16 17:25
spinbox.tcl	4.16 KB	-rw-r--r--	2019-10-16 17:25
treeview.tcl	8.65 KB	-rw-r--r--	2019-10-16 17:25
ttk.tcl	4.44 KB	-rw-r--r--	2019-10-16 17:25
utils.tcl	8.36 KB	-rw-r--r--	2019-10-16 17:25
vistaTheme.tcl	9.12 KB	-rw-r--r--	2019-10-16 17:25
winTheme.tcl	2.58 KB	-rw-r--r--	2019-10-16 17:25
xpTheme.tcl	1.88 KB	-rw-r--r--	2019-10-16 17:25

Rename

#
# Bindings for Buttons, Checkbuttons, and Radiobuttons.
#
# Notes: <Button1-Leave>, <Button1-Enter> only control the "pressed"
# state; widgets remain "active" if the pointer is dragged out.
# This doesn't seem to be conventional, but it's a nice way
# to provide extra feedback while the grab is active.
# (If the button is released off the widget, the grab deactivates and
# we get a <Leave> event then, which turns off the "active" state)
#
# Normally, <ButtonRelease> and <ButtonN-Enter/Leave> events are 
# delivered to the widget which received the initial <ButtonPress>
# event.  However, Tk [grab]s (#1223103) and menu interactions
# (#1222605) can interfere with this.  To guard against spurious
# <Button1-Enter> events, the <Button1-Enter> binding only sets
# the pressed state if the button is currently active.
#

namespace eval ttk::button {}

bind TButton <Enter> 		{ %W instate !disabled {%W state active} }
bind TButton <Leave>		{ %W state !active }
bind TButton <Key-space>	{ ttk::button::activate %W }
bind TButton <<Invoke>> 	{ ttk::button::activate %W }

bind TButton <ButtonPress-1> \
    { %W instate !disabled { ttk::clickToFocus %W; %W state pressed } }
bind TButton <ButtonRelease-1> \
    { %W instate pressed { %W state !pressed; %W instate !disabled { %W invoke } } }
bind TButton <Button1-Leave> \
    { %W state !pressed }
bind TButton <Button1-Enter> \
    { %W instate {active !disabled} { %W state pressed } }

# Checkbuttons and Radiobuttons have the same bindings as Buttons:
#
ttk::copyBindings TButton TCheckbutton
ttk::copyBindings TButton TRadiobutton

# ...plus a few more:

bind TRadiobutton <KeyPress-Up> 	{ ttk::button::RadioTraverse %W -1 }
bind TRadiobutton <KeyPress-Down> 	{ ttk::button::RadioTraverse %W +1 }

# bind TCheckbutton <KeyPress-plus> { %W select }
# bind TCheckbutton <KeyPress-minus> { %W deselect }

# activate --
#	Simulate a button press: temporarily set the state to 'pressed',
#	then invoke the button.
#
proc ttk::button::activate {w} {
    $w instate disabled { return }
    set oldState [$w state pressed]
    update idletasks; after 100	;# block event loop to avoid reentrancy
    $w state $oldState
    $w invoke
}

# RadioTraverse -- up/down keyboard traversal for radiobutton groups.
# 	Set focus to previous/next radiobutton in a group.
#	A radiobutton group consists of all the radiobuttons with
#	the same parent and -variable; this is a pretty good heuristic
#	that works most of the time.
#
proc ttk::button::RadioTraverse {w dir} {
    set group [list]
    foreach sibling [winfo children [winfo parent $w]] {
    	if {   [winfo class $sibling] eq "TRadiobutton"
	    && [$sibling cget -variable] eq [$w cget -variable]
	    && ![$sibling instate disabled]
	} {
	   lappend group $sibling
	}
    }

if {![llength $group]} {	 # Shouldn't happen, but can.
    	return
    }

set pos [expr {([lsearch -exact $group $w] + $dir) % [llength $group]}]
    tk::TabToWindow [lindex $group $pos]
}